home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 008 / alpha.arc / SYSAR3W.BAS < prev    next >
Encoding:
BASIC Source File  |  1986-11-09  |  4.5 KB  |  111 lines
  1. 10 DEF FNPHLP1(W,WC,D) = -ATN(W/WC)
  2. 20 DEF FNPHHP1(W,WC,D) =  ATN(WC/W)
  3. 30 DEF FNPHLP2(W,WC,D) = -ATN( D*W /(WC*(1.000001-(W/WC)^2 ) ) ) + PI*(W>WC)
  4. 40 DEF FNPHHP2(W,WC,D) =  ATN( D*WC/(W *(1.000001-(WC/W)^2 ) ) ) - PI*(W<WC)
  5. 50 DEF FNAMLP1(W,WC,D) = 1 / SQR(1!+(W/WC)^2)
  6. 60 DEF FNAMHP1(W,WC,D) = 1 / SQR(1!+(WC/W)^2)
  7. 70 DEF FNAMLP2(W,WC,D) = 1 / SQR(1+(W/WC)^4+(D*D-2!)*(W/WC)^2)
  8. 80 DEF FNAMHP2(W,WC,D) = 1 / SQR(1+(WC/W)^4+(D*D-2.000001)*(WC/W)^2)
  9. 90 DEF FNDBV(AMP)      = 20!*LOG(AMP)/LOG(10!)
  10. 100 DEF FNPHD(RAD)     = 180!*RAD/PI
  11. 110 DEF FNSUMA(AA,AB,PA,PB) = SQR((AA*SIN(PA)+AB*SIN(PB))^2 + (AA*COS(PA)+AB*COS(PB))^2 )
  12. 120 DEF FNSUMPW(AA,AB,PA,PB) = SQR((AA*AA*SIN(PA)+AB*AB*SIN(PB))^2 +                                               (AA*AA*COS(PA)+AB*AB*COS(PB))^2 )
  13. 130 DEF FNSUMPN(AA,AB,PA,PB) =   AA*SIN(PA)+AB*SIN(PB)
  14. 140 DEF FNSUMPD(AA,AB,PA,PB) =   AA*COS(PA)+AB*COS(PB)
  15. 150 DEF FNDIRF(AA,AB,PA,PB) = ABS((SIN((PA-PB))*(((AA >= AB)*AB/AA)+((AB > AA)*AA/AB)  )))
  16. 160 PI = ATN(SQR(3!))*3
  17. 170 DIM FREQT(10)
  18. 180 FREQT(1)=20:FREQT(2)=25:FREQT(3)=32:FREQT(4)=40:FREQT(5)=50:FREQT(6)=64:
  19. 190 FREQT(7)=80:FREQT(8)=100:FREQT(9)=128:FREQT(10)=160
  20. 200 REM   Crossover characteristics
  21. 210 FCL = 65.1 :QCL = 1.307
  22. 215 FCL2  = 65.1 :QCL2  = .543
  23. 220 FCH = 65! :QCH = .600
  24. 221 print "Enter QCL1 or hit enter for ";QCL
  25. 222 input ANS
  26. 223 if ans > 0 then QCL = ans
  27. 231 print "Enter QCL2 or hit enter for ";QCL2
  28. 232 input ANS
  29. 233 if ans > 0 then QCL2 = ans
  30. 241 print "Enter QCH1 or hit enter for ";QCh
  31. 242 input ANS
  32. 243 if ans > 0 then QCh = ans
  33. 250 REM   driver characteristics
  34. 255 FLB = 25!  :QLB = 1.307
  35. 260 FLL = 25! :QLL = .543
  36. 270 FLH = 1000.01  :QLH = .15
  37. 280 FHL = 45! :QHL = 1.1
  38. 290 FHH = 1200!:QHH = 1.1
  39. 300 REM Upper driver is dist inches in front of lower driver
  40. 310 DIST = 0!
  41. 320 REM End of variables
  42. 323 WLB = FLB*2*PI
  43. 327 DLB = 1!/QLB
  44. 330 WCH = FCH*2*PI
  45. 340 WCL2 = FCL2*2*PI
  46. 345 DCL2 = 1!/QCL2
  47. 350 WCL = FCL*2*PI
  48. 355 DCL = 1!/QCL
  49. 360 DCH = 1!/QCH
  50. 370 WLL = FLL*2*PI
  51. 380 WLH = FLH*2*PI
  52. 390 DLL = 1!/QLL
  53. 400 DLH = 1!/QLH
  54. 410 WHL = FHL*2!*PI
  55. 420 WHH = FHH*2!*PI
  56. 430 DHL = 1!/QHL
  57. 440 DHH = 1!/QHH
  58. 450 GOSUB 790
  59. 460 FOR ID = 2 TO 4
  60. 470 FOR IO = 1 TO 10
  61. 480 IF ID = 5 AND IO > 1 THEN GOTO 770
  62. 490 F = FREQT(IO)*10^(ID-2)
  63. 500 IF F=1000! THEN GOSUB 790
  64. 510 W = F*2!*PI
  65. 520 REM      basic equations for response
  66. 530 LPPHAS = FNPHLP2(W,WCL,DCL) + FNPHLP2(W,WCL2,DCL2) + FNPHLP2(W,WLH,DLH) + FNPHHP2(W,WLL,DLL) + FNPHHP2(W,WLB,DLB)
  67. 540 LPGAIN = FNAMLP2(W,WCL,DCL) * FNAMLP2(W,WCL2,DCL2) * FNAMLP2(W,WLH,DLH) * FNAMHP2(W,WLL,DLL) * FNAMHP2(W,WLB,DLB)
  68. 550 HPPHAS = FNPHHP2(W,WCH,DCH) + FNPHHP2(W,WHL,DHL) + FNPHLP2(W,WHH,DHH)                + DIST * W /(12!*1100)
  69. 560 HPGAIN = FNAMHP2(W,WCH,DCH) * FNAMHP2(W,WHL,DHL) * FNAMLP2(W,WHH,DHH)
  70. 570 REM
  71. 580 DIRC   = FNDIRF(HPGAIN,LPGAIN,HPPHAS,LPPHAS)
  72. 590 AMPR   = FNSUMA(HPGAIN,LPGAIN,HPPHAS,LPPHAS)
  73. 591 AMPR = AMPR * FNAMHP2(W,WEL,DEL)^4
  74. 600 POWR   = FNSUMPW(HPGAIN,LPGAIN,HPPHAS,LPPHAS)
  75. 602 POWR = POWR * FNAMHP2(W,WEL,DEL)^4
  76. 610 PHASN  = FNSUMPN(HPGAIN,LPGAIN,HPPHAS,LPPHAS)
  77. 620 PHASD  = FNSUMPD(HPGAIN,LPGAIN,HPPHAS,LPPHAS)
  78. 630 PHAS   = ATN(PHASN/PHASD)
  79. 632 rem PHAS = PHAS * FNPHHP2(W,WEL,DEL)*2!
  80. 640 IF (PHASN<0! AND PHASD<0!)THEN PHAS = PHAS-PI
  81. 650 IF (PHASN>0! AND PHASD<0!)THEN PHAS = PI+PHAS
  82. 660 LPAMP  = FNDBV(LPGAIN)
  83. 670 HPAMP  = FNDBV(HPGAIN)
  84. 680 AMPRD  = FNDBV(AMPR)
  85. 690 POWRD  = FNDBV(POWR)*.5
  86. 700 HPPHAS = FNPHD(HPPHAS)
  87. 710 PHASD  = FNPHD(PHAS)
  88. 720 LPPHAS = FNPHD(LPPHAS)
  89. 730 PRINT USING"######  ####.## ####.##  ####.## ####.## #.## ###.## ###.## ###.## ####.##";F;LPPHAS;LPAMP;HPPHAS;HPAMP;DIRC;HPPHAS-LPPHAS,AMPRD,POWRD,PHASD
  90. 740 NEXT IO
  91. 750 NEXT ID
  92. 760 PRINT" "
  93. 770 rem LIST 200-250
  94. 780 STOP
  95. 790 PRINT " "
  96. 800 PRINT "Lower Crossover (1) at:";FCL;" Q:";QCL
  97. 805 PRINT "Lower Crossover (2) at:";FCL2;" Q:";QCL2
  98. 810 PRINT "Upper Crossover at:";FCH;" Q:";QCH
  99. 820 PRINT "   Lower driver (1) lower Fc:";FLL;" Q:";QLL
  100. 825 PRINT "   Lower driver (2) lower Fc:";FLB;" Q:";QLB
  101. 830 PRINT "   Lower driver upper Fc:";FLH;" Q:";QLH
  102. 840 PRINT "   Upper driver lower Fc:";FHL;" Q:";QHL
  103. 850 PRINT "   Upper driver upper Fc:";FHH;" Q:";QHH
  104. 860 PRINT "Upper driver is:";DIST;" Inches in front of lower driver"
  105. 870 PRINT " "
  106. 880 PRINT "          Lower driver    Upper driver
  107. 890 PRINT "        ---------------- --------------
  108. 900 PRINT " Freq    phase   amp,dB   phase  amp,dB  Dirf Ph Diff  Vsum   Psum  Phsum"
  109. 910 PRINT "------  ------- -------- ------- ------- ---- ------- ------ -----  -----"
  110. 920 RETURN
  111.